《ANSYS在机械与化工装备中的应用》一书中，高压容器筒体与封头的连接区域的应力分析的例子中，采用PLANE82单元建立模型，并设定轴对称选项，筒体下端各节点约束轴向位移，球壳对称面上各节点约束水平方向位移，内壁施加均匀压力面载荷。加载情况见图1。

       对于2D结构实体单元，在设定了轴对称选项的情况下，球壳对称面上各节点是否有必要约束水平方向的位移？首先，对比一下两种情况下的计算结果，结果见图2和图3。

     综上所述，球壳对称面上各节点是否约束水平方向的位移对于结果的影响不大，应该是由于球壳的厚度相对于其它尺寸要小很多，但对实心杆这样的实体结构的轴对称模型，就必须施加沿对称轴的UX约束。  
 

图2 球壳对称面上各节点施加X向约束

图3 球壳对称面上各节点未施加X向约束

 

!!!!!!!参数设定!!!!!!!!!
R1=775       !筒体内半径
T1=100       !筒体厚度
R2=800       !球壳内半径
T2=48        !球壳厚度
L=95         !筒体削边长度
LC=1200      !筒体长度
P=16         !内压
E=2E5        !弹性模量
NU=0.3       !泊松比
NT=5         !厚度方向剖分数
NS=30        !球壳经向剖分数
NC=30        !筒体轴向剖分数
NL=5         !过渡段剖分数
RA=0.6       !剖分比例
!!!!!!!前处理!!!!!!!
/PREP7
ET,1,PLANE82,,,1     !定义单元类型
KEYOPT,1,3,1         !设定轴对称选项
MP,EX,1,E            !定义材料的弹性模量
MP,NUXY,1,NU         !定义材料的泊松比
!!!!!!建立模型!!!!!!!
CYL4,,,r2,,r2+t2,90  !生成球冠封头
RECTNG,R1,R1+T1,0,-LC   !生成筒体
WPOFFS,,L               !工作平面Y向移动L
WPROTA,,90              !旋转工作平面YX 90度
ASBW,ALL                !用工作平面分割球封头
ADELE,4,,,1             !删除4面
A,7,8,10,9              !生成过渡段
!!!!!!!!划分网格!!!!!
LSEL,S,LOC,X,R1
LSEL,A,LOC,X,R1+T1
LESIZE,ALL,,,NC
ALLSEL
LSEL,S,LOC,Y,0
LSEL,A,LOC,Y,L
LSEL,A,LOC,Y,-LC
LSEL,A,LOC,X,0
LESIZE,ALL,,,NT
ALLSEL
CSYS,1
LSEL,S,LOC,X,R2
LSEL,A,LOC,X,R2+T2
LESIZE,ALL,,,NS
CSYS,0
ALLSEL
LSEL,S,LOC,Y,0,L
LSEL,U,LOC,Y,0
LSEL,U,LOC,Y,L
LESIZE,ALL,,,NL
ALLSEL
AMESH,ALL
FINISH
!!!!!!!!!求解!!!!!
/SOLU                !进入求解器
LSEL,S,LOC,X,0       !选择球封头端面
DL,ALL,,UX           !施加UX约束
LSEL,S,LOC,Y,-LC     !选择筒体端面
DL,ALL,,UY           !施加UY约束
ALLSEL
LSEL,S,LOC,X,0,R2
LSEL,U,LOC,X,0
LSEL,U,RADIUS,,R2+T2
SFL,ALL,PRES,P
ALLSEL
SOLVE
FINISH
!!!!!!!!后处理!!!!!!!!
/POST1
PLNSOL,S,INT,2,1
FINI